Code-a-holic: [VBScript] Boost - changing process priority using WMI

Friday, March 16, 2007

[VBScript] Boost - changing process priority using WMI

I have little sh script on my iBook which changes the priority of a given process so that the OS services it more frequently, giving the impression of faster execution. Below is a re-implementation in VBScript of a similar tool for Windows. First a few constants and the arrays that handle the commandline options.

Option Explicit

Const LOW_PRIORITY = 64 '1
Const BELOWNORMAL_PRIORITY = 16384 '2
Const NORMAL_PRIORITY = 32 '3
Const ABOVENORMAL_PRIORITY = 32768 '4
Const HIGH_PRIORITY = 256 '5
Const REALTIME_PRIORITY = 128 '6

Dim aNames
Dim aValues

aNames = Array( "LOW", "BELOWNORMAL", "NORMAL", "ABOVENORMAL", "HIGH", "REALTIME" )
aValues = Array( LOW_PRIORITY, BELOWNORMAL_PRIORITY, NORMAL_PRIORITY, ABOVENORMAL_PRIORITY, HIGH_PRIORITY, REALTIME_PRIORITY )

Next, the real meat of this tool: the Windows Management Interface (WMI) call which takes a string and a numeric defining the process name and the priority level.

Function SetPriority( sProcess, nPriority )
    Dim sComputer
    Dim oWMIService
    Dim cProcesses
    Dim oProcess
    Dim bDone
    
    bDone = False
    sComputer = "."
    Set oWMIService = GetObject("winmgmts:\\" & sComputer & "\root\cimv2")

    Set cProcesses = oWMIService.ExecQuery _
        ("Select * from Win32_Process Where Name = '" & sProcess & "'")
    For Each oProcess in cProcesses
        oProcess.SetPriority( nPriority )
        bDone = True        
    Next
    SetPriority = bDone
End Function

Next a few less inspiring routines: IIF (available in VB but not in VBScript), ArrayOffset, and HelpText.

Function IIF( bCondition, vTrue, vFalse )
    Dim vResult
    If bCondition = True Then
        vResult = vTrue
    Else
        vResult = vFalse
    End If
    IIF = vResult
End Function

Function ArrayOffset( sItem, aList )
    Dim i
    Dim u
    Dim nResult
    nResult = -1
    For i = 0 To UBound( aList )
        If sItem = aList( i ) Then
            nResult = i
            Exit For
        End If
    Next
    ArrayOffset = nResult
End Function

Sub HelpText
    WScript.Echo "Syntax:"
    WScript.Echo vbTab & "Boost {appName} /L:{priority}"
    WScript.Echo vbTab & "priority: LOW | BELOWNORMAL | NORMAL | ABOVENORMAL | HIGH | REALTIME"
    WScript.Echo 
    WScript.Echo vbTab & "E.g. boost cscript.exe /l:realtime"
End Sub

Finally the main routine, which uses Named and Unnamed Arguments to handle command line parameters. The name of the process is pulled out of the command line using an Unnamed Argument, and the text representation of the priority is pulled out using a Named Argument ("L"). If the priority is acceptable the name and priority are passed to the SetPriority routine.

If WScript.Arguments.Unnamed.Count = 0 Or WScript.Arguments.Named.Count = 0 Then
    HelpText
    WScript.Quit
End If

Dim sApp, sPrio, nOffs

sApp = WScript.Arguments( 0 ) 
sPrio = WScript.Arguments.Named.Item("L")
nOffs = ArrayOffset( UCase( sPrio ), aNames ) 
If nOffs = -1 Then
    WScript.Echo "The",sPrio,"priority cannot be assigned to",sApp
    HelpText
Else
    WScript.Echo sApp, _
        IIF( SetPriority( sApp, aValues( nOffs ) ), _
            "boosted to " & aNames( nOffs ) & " priority", _
            "not boosted" ) 
End If

A further refinement of this tool might be to provide for one other possibility for /L: 'KILL' or 'TERMINATE'. By way of comparison here's the original sh script.

#!/bin/sh
ps axxw | grep $1 | grep -v grep | grep -v boost 
sudo renice -20 `ps axww | grep $1 | grep -v grep | grep -v boost | awk '{print $1}'`

Friday, March 16, 2007

[VBScript] Boost - changing process priority using WMI

No comments: