Code-a-holic: [VBScript] Classes, classes, classes

Over at Win32Scripting where I've been hanging out of late, some bright spark, Tony Hinkle by name, put up code to

"Use IE as an output device! This script is an example of how to make a DIV element an object and then change the innerHTML property. This is a vbs file, not an .asp file. ..."

Being adventurous, I turned it into a class and added a bit of WMI to get the screen dimensions.

class IEDisplay
    '~ Based on original work by Tony Hinkle, tonyhinkle@yahoo.com
    
    private TEMPORARY_FOLDER
    
    private objShell
    private objIE
    private objFSO
    private objFolder
    private strName
    private streamOut
    private objDIV
    
    private numHeight
    private numWidth
    private numTop
    private numLeft
    
    private sub Class_Initialize()
        Dim strComputer
        Dim objWMIService
        Dim colItems
        Dim objItem
        Dim arrMonitors( 10, 1 )
        Dim numMonitorCount
        
        Set objShell = WScript.CreateObject("WScript.Shell")
        Set objIE = CreateObject("InternetExplorer.Application")
        
        strComputer = "."
        Set objWMIService = GetObject( "winmgmts:\\" & strComputer & "\root\cimv2")
        Set colItems = objWMIService.ExecQuery( "Select  * from Win32_DesktopMonitor")
        
        numMonitorCount = 0 
        For Each objItem in colItems
            arrMonitors( numMonitorCount, 0 ) = objItem.ScreenHeight
            arrMonitors( numMonitorCount, 1 ) = objItem.ScreenWidth
            numMonitorCount = numMonitorCount + 1
        Next
        
        numHeight = arrMonitors( 0, 0 )
        numWidth = arrMonitors( 0, 1 )
        
        '~ MsgBox numHeight & " " & numWidth
        
        Set objFSO = CreateObject("Scripting.FileSystemObject")
        TEMPORARY_FOLDER = 2
        set objFolder = objFSO.GetSpecialFolder( TEMPORARY_FOLDER )
        '~ strName = objFolder.Path & "\" & objFSO.GetTempName & ".html"
        strName = objFSO.GetTempName
        '~ WScript.Echo strName
        set streamOut = objFolder.CreateTextFile( strName, True )
        
        streamOut.WriteLine("<HTML><HEAD><TITLE>Information</TITLE></HEAD>")
        streamOut.WriteLine("<BODY SCROLL='NO'><CENTER><FONT FACE='arial black'> <HR COLOR='BLACK'>")
        streamOut.WriteLine("<DIV id='MakeMeAnObject'></DIV>")
        streamOut.WriteLine("<HR COLOR='BLACK'></FONT></CENTER></BODY></HTML>")
        streamOut.Close
        
        numTop = 0
        numLeft = 0
    end sub
    
    Sub Init( strPosition )
        'NW, N, NE, W, CENTRE, E, SW, S, SE
        Select Case strPosition
        Case "NW"
            numTop = 0
            numLeft = 0
        Case "N"
            numTop = 0
            numLeft = ( numWidth / 2 ) - 250
        Case "NE"
            numTop = 0
            numLeft = numWidth - 500
        Case "W"
            numTop = ( numHeight / 2 ) - 55
            numLeft = 0
        Case "CENTRE"
            numTop = ( numHeight / 2 ) - 55
            numLeft = ( numWidth / 2 ) - 250
        Case "E"
            numTop = ( numHeight / 2 ) - 55
            numLeft = numWidth - 500
        Case "SW"
            numTop = numHeight - 110
            numLeft = 0
        Case "S"
            numTop = numHeight - 110
            numLeft = ( numWidth / 2 ) - 250
        Case "SE"
            numTop = numHeight - 110
            numLeft = numWidth - 500
        Case Else
            numTop = 0
            numLeft = 0
        End Select
            
        SetupIE( objFolder.Path & "\" & strName )
        Set objDIV = objIE.Document.All("MakeMeAnObject")
        '~ wscript.echo typename(objdiv)
    end sub


    private sub Class_Terminate()
        'Close IE and delete the file
        objIE.Quit
        '~ optionally you may want to get rid of the temp file
    end sub
    
        
    public sub Display( strMsg, numMillisec )
        '~ wscript.echo typename(objdiv)
        '~ MsgBox TypeName( numMillisec )
        objDIV.InnerHTML = strMsg
        WScript.Sleep numMillisec
    end sub
    
    Private Sub SetupIE(File2Load)
         objIE.Navigate File2Load
         objIE.ToolBar = False
         objIE.StatusBar = False
         objIE.Resizable = False
    
         Do
         Loop While objIE.Busy
    
         objIE.Width = 500
         objIE.Height = 110
         objIE.Left = numLeft
         objIE.Top = numTop
         objIE.Visible = True
         objShell.AppActivate("Microsoft Internet Explorer")
    End Sub

end class

And some test code which puts boxes at 9 different points on the screen:

set x = new iedisplay
dim a
a = split("NE,N,NW,SE,S,SW,E,CENTRE,W",",")
for i = 0 to ubound(a)
 x.Init a(i)
 x.Display "Woof",10
next

Code-a-holic

Monday, September 19, 2005

[VBScript] Classes, classes, classes

No comments:

Post a Comment