[Clipper 5.3 / xHarbour] .DBF to .CH (Clipper Header)

The client had Clipper 5.3. I had xHarbour. The client had a database of constants. I turned them into a .ch (Clipper Header) file with this bit of code which compiled both under xHarbour and Clipper 5.

procedure main()
        local cFName, vFValue
        local cCValue, cCName
        local nMax, i
        local h
        local cType
        local CRLF := CHR(13)+CHR(10)
        local cLine

        h := FCREATE( "./dispense.ch", 0 )
        ? h
        use numbers alias num
        goto 1
        nMax := FCOUNT()
        for i = 1 to nMax
                cFName := FIELDNAME( i )
                *? cFName
                cCName := "CONST_" + cFName
                vFValue := &cFName
                cType := VALTYPE(vFValue)
                *? cType
                DO CASE 
                        CASE cType == "C"
                                cCValue := '"' + vFValue + '"'
                        CASE cType == "N"
                                cCValue := STR( vFValue )
                        CASE cType == "D"
                                cCValue := DTOC( vFValue )
                        CASE cType == "L"
                                cCValue := IIF( vFValue, ".T.", ".F." )
                        OTHERWISE
                                ? "Don't know what to do with a cType of " + cType
                                QUIT
                END CASE
                cLine := "#define " + cCName + " " + cCValue + CRLF 
                ? cLine
                FWRITE( h, cLine )
                

        next
        FCLOSE( h )
        CLOSE DATABASES
        QUIT