Code-a-holic: anonymous subroutines

Tuesday, March 11, 2008

[Perl] How to do it better

There are some really helpful people in the Perl community. I advertised the original posting on comp.lang.perl.misc and received some very useful responses from John W. Krahn and Michele Dondi, as below.

With respect to the rules, John wrote:

# Rule 1. Remove all 's' 
sub rule1 {
   ( my $arg = shift ) =~ tr/s//d;
   return $arg;
}

# Rule 2. Sort the characters of the word into alphabetic order 
sub rule2 {
   return join '', sort split //, shift;
}

John> Why [were] you converting the '|' character and the 'e' character to 'e'?

# Rule 3. Convert all vowels to 'e 
sub rule3 {
     ( my $arg = shift ) =~ tr/aiou/e/;
     return $arg;
}

John> The . character class matches a lot more than just letters, or did you really mean "replace any first character except newline with 'n'".

# Rule 4. Replace the first letter with 'n' 
sub rule4 {
   ( my $arg = shift ) =~ s/\A[[:alpha:]]/n/;
   return $arg;
}

John> The . character class matches a lot more than just letters.

# Rule 5. Drop the last letter 
sub rule5 {
   ( my $arg = shift ) =~ s/[[:alpha:]]\z//;
   return $arg;
}

# Rule  6. Replace letter pairs with 'ow'
sub rule6 {
   ( my $arg = shift ) =~ s/([[:lower:]])\1/ow/g;
   return $arg;
}

Then, with respect to the string eval() of each rule, John said, "Ouch! Use a dispatch table instead of string eval()."

my %rule = (
     1 => sub {
         ( my $arg = shift ) =~ tr/s//d;
         return $arg;
         },
     2 => sub {
         return join '', sort split //, shift;
         },
     3 => sub {
         ( my $arg = shift ) =~ tr/aiou/e/;
         return $arg;
         },
# more rules here
     );

# and later on, use rules
     $res = $rule{ $j }( $arg ); 

At this point Michele Dondi chipped in with, ">my %rule = (
>  1 => sub {
>    ( my $arg = shift ) =~ tr/s//d;
>    return $arg;
>    },
>  2 => sub {
>    return join '', sort split //, shift;
>    },

Since the keys are numbers, an array may be appropriate."

So there you have it, better rules, anonymous subroutines, and hashes. Powerful stuff.

I wonder how Tcl and the other languages would have done it. Or Protium, for that matter. Any takers?

© Copyright Bruce M. Axtens, 2008