Code-a-holic: December 2005

Monday, December 19, 2005

[VBScript] Deriving user name from computer name

I found a brilliant bit of code for deriving the username from the computer name. It's found inside Matt Williams's "ManagePC v1.31" HTA. His description of the routine is as follows

This bit of code is "cheating" slightly in that all it's doing is getting the owner of the explorer.exe process. Seeing as explorer.exe only runs if a user is logged on it is a reliable (but sneaky) way of getting the logged-on user. It does, however, mean that even if a user is logged on locally or the account is a generic account, it will retrieve the correct values (WMI cannot do this).
-- Matthew Williams, ManagePC

Below is my routine, combining his code with some extra housekeeping.

Function GetDomainUser( sComputer )
 Dim cProc
 Dim oProcess
 Dim sUser, sDomain
 Dim sResult
 Dim oWMI
 
 sResult = "<not switched on>"
 If ResolveIP( sComputer ) <> Empty Then

  On Error Resume Next
  Set oWMI = GetObject("winmgmts:\\" & sComputer & "\root\CIMV2")
  If Err.Number = 0 Then
   Set cProc = oWMI.ExecQuery("Select Name from Win32_Process Where Name='explorer.exe' and  SessionID=0")
   
   If cProc.Count > 0 Then
    For Each oProcess In cProc
     oProcess.GetOwner sUser, sDomain
     sResult = sDomain & "\" & sUser
    Next
    Else
    sResult = "<not logged on>"
   End If
   Err.Clear
   On Error Goto 0
  End If
 End If
 GetDomainUser = sResult
End Function

Of course, if no one is logged in, you get nothing. My own take on Matt's routine adds in a check to see if the computer is actually running, using ResolveIP() below:

Function ResolveIP( sName )
 Dim sHost
 Dim sTarget
 Dim cPingResults
 Dim oPingResult
 Dim sResult
 
 sResult = ""
 sHost = oNetwork.ComputerName
 sTarget = sName
 
 Set cPingResults = GetObject("winmgmts:{impersonationLevel=impersonate}//" & _
        sHost & "/root/cimv2"). ExecQuery("SELECT * FROM Win32_PingStatus " & _
        "WHERE Address = '" + sTarget + "'")

 For Each oPingResult In cPingResults
  If oPingResult.StatusCode = 0 Then
   sResult = oPingResult.ProtocolAddress
  End If
 Next
 ResolveIP = sResult
End Function

[VBScript] Plugins

I had written a plugin architecture for one of my HTA applications. Now I discover that I can have plugins using almost any scripting language available. I found this bit of brilliance in a google search: I can now pass whatever information I like to and fro from application to plugin and back again. And if another scripting languages does something better than VBScript I can use it (provided it gives access to the volatile store).

Wednesday, December 07, 2005

[Working Again]

After a short stint on the support queue at iiNet (part-time), I'm now on contract at Department of Land Information. L1 and L2 support with a bit of scripting on the side. VBScript again, sadly.