Code-a-holic: Broggle - a blogging tool in an HTML application

Thursday, August 18, 2005

Broggle - a blogging tool in an HTML application

Okay, now a quick shift from straight VBScript to VBScript inside an HTML application. It's to deal with formatting issues I have with Blogger. The solution is probably way simpler than this.

Saved as Broggle.hta and then double-click launched in Explorer.

Just put "#code" and "#endcode" around code and "#text" and "#endtext" around text, click on [Evaluate], then click on [Copy to Clipboard], and then paste into the blog.

<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<HTML><HEAD>
<META http-equiv=Content-Type content="text/html; charset=windows-1252">
<META content="MSHTML 6.00.2800.1480" name=GENERATOR>
<HTA:APPLICATION id=oHTA scroll="no" 
showInTaskBar="yes" caption="yes" applicationName="Broggle" 
CONTEXTMENU="yes" SYSMENU="yes" singleInstance="yes" maximizeButton="no">
<SCRIPT language=VBScript>

Sub Evaluate( theText )
  Dim theList, theMax, i, theLine
  Dim theResult
  Dim inCode
  Dim theTemp
  
  theResult = ""
  theList = Split( theText, vbCRLF )
  theMax = UBound( theList )


  inCode = False
  For i = 0 to theMax
    theLine = theList( i )


    If Left( theLine, 5 ) = "#text" Then
      theResult = theResult & "<span style=""font-family: georgia;"">"


    ElseIf Left( theLine, 8 ) = "#endtext" Then
      theResult = theResult & "</span><br><br>"


    ElseIf Left( theLine, 5 ) = "#code" Then
      theResult = theResult & "<span style=""font-family: courier new;""><pre>"
      inCode = True
      
    ElseIf Left( theLine, 8 ) = "#endcode" Then
      theResult = theResult & "</pre></span><br><br>"
      inCode = False
      
    ElseIf theLine = "" Then
      If inCode = False Then
        theResult = theResult & "<br><br>" & vbCRLF
      Else
        theResult = theResult & vbCRLF
      End If
      
    Else
      If inCode = True Then
        theTemp = theLine
        theTemp = Replace( theTemp, "&", "&amp;" )
        theTemp = Replace( theTemp, "<", "&lt;" )
        theTemp = Replace( theTemp, ">", "&gt;" )
        theResult = theResult & theTemp & vbCRLF
      Else
        theResult = theResult & theLine & vbCRLF
      End If
    End If


    'MsgBox theResult
  Next
  tSlave.value = theResult
End Sub


Sub bEvaluate_Click()
  if tMaster.value = "" Then
    MsgBox "Can't evaluate nothing",,"Broggle"
  Else
    Evaluate tMaster.value
  End If
End Sub


Sub bCopy_Click()
  if tSlave.Value = "" Then
    MsgBox "Can't copy nothing.",,"Broggle"
  Else
    document.parentwindow.clipboardData.SetData "text", tSlave.Value
  End If
End Sub

</SCRIPT>
</HEAD>
<BODY>
<P><INPUT id=bEvaluate onclick=bEvaluate_Click type=button value=Evaluate name=bEvaluate></P>
<P><TEXTAREA id=tMaster style="WIDTH: 578px; HEIGHT: 130px" name=tMaster rows=6 cols=61></TEXTAREA>&nbsp;</P>
<P><TEXTAREA id=tSlave style="WIDTH: 579px; HEIGHT: 166px" name=tSlave rows=8 cols=62></TEXTAREA>&nbsp;</P>
<P><INPUT id=bCopy onclick=bCopy_Click type=button value="Copy to Clipboard"></P>
<P>&nbsp;</P></BODY></HTML>

Thursday, August 18, 2005

Broggle - a blogging tool in an HTML application

No comments: