Code-a-holic: [VBScript/HTA] Broggle on Steroids

Thursday, August 25, 2005

[VBScript/HTA] Broggle on Steroids

Big changes to Broggle.hta. No more #code/#endcode etc. Just #text, #code, #quot and #end. Now the HTA is more in line with the MetaCard and Tcl version at home on the iBook. I've also put in a preview button (which should probably be somewhere other than where it is right now) which puts the conversion results into a <DIV> at the bottom (thus the scrollbar at the side.)

Enjoy

<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<HTML><HEAD>
<HTA:APPLICATION id=oHTA
scroll="yes" showInTaskBar="yes" caption="yes" applicationName="Broggle"
CONTEXTMENU="yes" SYSMENU="yes" singleInstance="yes" maximizeButton="no">
<SCRIPT language=VBScript>
ResizeTo 631,500

Dim lastMark
Dim inCode

Function stopMarkup( mark )
    Dim res
    Select Case mark
    Case "code"
        res = "</pre></span>"
        inCode = False
    Case "quot"
        res = "</blockquote>"
    Case "text"
        res = "</span>"
    case "end"
        res = ""
    End Select
    stopMarkup = res
End Function

Function startMarkup( mark )
    Dim res
    res = stopMarkup( lastMark )
    Select Case mark
    Case "code"
        res = res & "<span style=""font-family: courier new;""><pre>"
        inCode = True
    Case "quot"
        res = res & "<blockquote>"
    Case "text"
       res = res & "<span style=""font-family: georgia;"">"
    case "end"
        'If lastMark = "code" or lastMark = "text" Then
        '    res = res & "</span>"
        'Else
            res = res & ""
        'End If
    End Select
    startMarkup = res
End Function

Sub Evaluate( theText )
  Dim theList, theMax, i, theLine
  Dim theResult
  Dim theTemp
  Dim markup

  theResult = ""
  theList = Split( theText, vbCRLF )
  theMax = UBound( theList )
  lastMark = ""
  inCode = False
  For i = 0 to theMax
    theLine = theList( i )

    If Left( theLine, 1 ) = "#" Then
        markup = Mid( theLine, 2 )
        TheResult = theResult & startMarkup( markup )
        lastMark = markup
    Else
        If theLine = "" Then
            theResult = theResult & "<BR><BR>"
        Else
          If inCode = True Then
            theTemp = theLine
            If theTemp = "" Then
                theTemp = "<BR><BR>"
            Else
                theTemp = Replace( theTemp, "&", "&amp;" )
                theTemp = Replace( theTemp, "<", "&lt;" )
                theTemp = Replace( theTemp, ">", "&gt;" )
            End If
            theResult = theResult & theTemp & vbCRLF
          Else
            theResult = theResult & theLine & vbCRLF
          End If
        End If
    End If

    'MsgBox theResult
  Next
  if lastMark <> "end" Then theResult = theResult & stopMarkup( lastMark )
  tSlave.value = theResult
End Sub

Sub bEvaluate_Click()
  if tMaster.value = "" Then
    MsgBox "Can't evaluate nothing",,"Broggle"
  Else
    Evaluate tMaster.value
  End If
End Sub

Sub bCopy_Click()
  if tSlave.Value = "" Then
    MsgBox "Can't copy nothing.",,"Broggle"
  Else
    document.parentwindow.clipboardData.SetData "text", tSlave.Value
  End If
End Sub

Sub bPreview_Click
    If tSlave.Value <> "" Then
        preview.innerHTML = tSlave.Value
    End If
End Sub

Sub bScreen_Click
  v3.Value = document.body.clientHeight
  v4.Value = document.body.clientWidth
<BR><BR>End Sub
</SCRIPT>
</HEAD>
<BODY>
<P align=left><INPUT id=bEvaluate onclick=bEvaluate_Click type=button value=Convert name=bEvaluate></P>
<P><TEXTAREA id=tMaster style="WIDTH: 578px; HEIGHT: 130px" name=tMaster rows=6 cols=61></TEXTAREA>&nbsp;</P>
<P><TEXTAREA id=tSlave style="WIDTH: 579px; HEIGHT: 166px" name=tSlave rows=8 cols=62></TEXTAREA>&nbsp;</P>
<P><INPUT id=bCopy onclick=bCopy_Click type=button value="Copy to Clipboard">&nbsp;<INPUT id="bPreview" onclick="bPreview_Click" type=button value="Preview"></P>
<HR>
<DIV id="preview"></DIV>
</BODY></HTML>

Thursday, August 25, 2005

[VBScript/HTA] Broggle on Steroids

No comments: